PDA

X Для форума GoHa.Ru теперь доступен мобильный стиль. Подробнее...

Просмотр полной версии : Облегчения UI в DarkFall


shtirliz
15.09.2010, 12:09
Играю чуть меньше месяца и столкнулся с проблемой удобства UI.
Вчера начал решать данную проблему и добился некоторых успехов.:lalala:
У меня мышь Razer Naga, также использовал программу AutoHotKey.

Список того, что мне удалось сделать:

1) Написал макрос для автохоткей
- отдельные хоткеи для переключения оружия с запоминаем состояния (двуручный меч, лук, стафф), т.е. если оружие было взят в руки, то при повторном нажатии оно не будет убираться.
- отдельный хоткей на хил - берется в руки стафф, проверяется откачен ли скил HealSelf, если откчан, то юзаем (выбор скила + левый клик), если не откачен, то юзается скил Stamina to Health. На практике очень удобно.
- отдельный хоткей на стамину - проверяется откачена ли жрачка, если откачена, то юзается, иначе берется в руки стафф и юзается скил Mana to Stamina.
- отдельный хоткей на скил WW для двуручного оружия - берется двуручник, выбирается скил WW и клик мышкой.
- отдельный хоткей на Rend (дебаф на пирсинг) - стафф в руки и юзаем скил с проверкой кулдауна.
- макрос на автоспринт.
2) Забиндил клавиши на мышку
1 - меч
2 - лук
3 - стафф
4 - ренд
5 - хил
6 - стамина

Надеюсь нубасам будет полезно:pilot:.

PS. Папки могут здесь давать советы:hapydancsmil:

Шорткаты в игре
меч - ctrl+1
лук - ctrl+2
стафф - ctrl + 3
скиннер - ctrl + 4

healself - alt+shift+1
stamina2health - alt+shift+2
mana2stamin - alt + shift + 3
rend - alt+shift + 4
food - alt+shift+5
Whirlwind - alt+shift+6


AHK шорткаты
alt+h - Heal (5 на мышке)
/ - Меч (1 на мышке)
' - Лук (2 на мышке)
\ - Стафф (3 на мышке)
. - скиннер (10 на мышке)
alt + j - Стамина (6 на мышке)
alt + k - Rend (4 на мышке)
q - Whirlwind
` - Jump 180
Правая кнопка мыши - тогл на sprint



#SingleInstance,Force
#MaxThreadsPerHotkey 2
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
WinActivate, Darkfall Online
Sleep, 200
#IfWinActive Darkfall Online
SoundPlay, %A_WinDir%\Media\ding.wav

; VARS ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;;
weapon = 0
sprint = 0

; TIMERS ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;

cast_healself := 4000
dura_healself := 30000
time_healself := A_TickCount - dura_healself

cast_mana2stam := 3500
dura_mana2stam := 4000
time_mana2stam := A_TickCount - dura_mana2stam

cast_stam2health := 3500
dura_stam2health := 4000
time_stam2health := A_TickCount - dura_stam2health

cast_rend := 2000
dura_rend := 6000
time_rend := A_TickCount - dura_rend

dura_food := 180000
time_food := A_TickCount - dura_food

dura_whirlwind := 9000
time_whirlwind := A_TickCount - dura_whirlwind

return

; REMAPPING ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;

Tab::MButton

Break::Suspend, Toggle

Home::Reload

; FUNCTIONS ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;

HealSpells()
{
global cast_healself, dura_healself, time_healself, cast_stam2health, dura_stam2health, time_stam2health

t1 := A_TickCount - time_healself
t2 := A_TickCount - time_stam2health

if (t1 > dura_healself)
{
staff()

Send !+{1}
Sleep, 250

Send {LButton}
Sleep, %cast_healself%

time_healself := A_TickCount
}
else if (t2 > dura_stam2health)
{
Staff()

Send !+{2}
Sleep, 250

Send {LButton}
Sleep, %cast_stam2health%

time_stam2health := A_TickCount
}
}

Stamina()
{
global dura_food, time_food, cast_mana2stam, dura_mana2stam, time_mana2stam

t1 := A_TickCount - time_food
t2 := A_TickCount - time_mana2stam

if (t1 > dura_food)
{
Send !+{5}
Sleep, 450

time_food := A_TickCount
}
else if (t2 > dura_mana2stam)
{
Staff()

Send !+{3}
Sleep, 250

Send {LButton}
Sleep, %cast_mana2stam%

time_mana2stam := A_TickCount
}
}

Rend()
{
global cast_rend, dura_rend, time_rend

t1 := A_TickCount - time_rend

if (t1 > dura_rend)
{
Staff()

Send !+{4}
Sleep, 250

Send {LButton}
Sleep, %cast_rend%

time_rend := A_TickCount
}
}



; FUNCS ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;

TwoSword()
{
global weapon
if not weapon = 2
{
Send ^{1}
Sleep, 250
}
weapon = 2
}

Bow()
{
global weapon
if not weapon = 3
{
Send ^{2}
Sleep, 250
}
weapon = 3
}

Staff()
{
global weapon
if not weapon = 4
{
Send ^{3}
Sleep, 250
}
weapon = 4
}

Skinner()
{
global weapon
if not weapon = 5
{
Send ^{4}
Sleep, 250
}
weapon = 5
}


Whirlwind()
{
global weapon, dura_whirlwind, time_whirlwind

t := A_TickCount - time_whirlwind

if (t > dura_whirlwind)
{
Sleep, 300
BlockInput On

TwoSword()

Send !+{6}
Sleep, 250

Send {LButton}
BlockInput Off
Sleep, 1200
time_whirlwind := A_TickCount
}
}

Jump180()
{
global weapon

Send {Space Down}
Sleep, 50
Send {Space Up}
if GetKeyState("w","P") && GetKeyState("LButton","P") && weapon > 2
{
Sleep, 50
DllCall("mouse_event",uint,1,int,-1250,int,0,uint,0,int,0)
Sleep, 750
DllCall("mouse_event",uint,1,int,1250,int,0,uint,0, int,0)
Sleep, 50
SoundPlay, %A_WinDir%\Media\ding.wav
}
}

GuiMode()
{
VarSetCapacity(mi,20,0)
mi:=chr(20)
DllCall("GetCursorInfo","Uint",&mi)
hCursor:=NumGet(mi,8) ; returns 0 for game-mode
return hCursor
}

;Sprint toggle
sprint()
{
global sprint
if sprint=0
{
SendInput {F12 down} ; F12 = sprint
sprint := 1
} else {
SendInput {F12 up} ; F12 = sprint
sprint := 0
}
}

; ASSIGN KEYS ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;

!h::HealSpells()
/::TwoSword()
'::Bow()
\::Staff()
.::Skinner()
!j::Stamina()
!k::Rend()
q::Whirlwind()
`::Jump180()
RButton:: sprint()

Роман Владимирович
15.09.2010, 12:38
Так то это не является облегчением, это является настройкой GUI под себя.

shtirliz
15.09.2010, 12:50
Так то это не является облегчением, это является настройкой GUI под себя.

Не каждый нубас может грамотно под себя настроить интерфейс. Хоть я и программир, но для меня было не просто....перерыл кучу сайтов в гугле для формирование начального представления.

Может этот топик поможет начать грамотно настраивать UI.

Например, мне многие реализованные идеи не понравились. Я отбираю наиболее интересные идеи, дорабатываю или генерирую новые. Основа какая-то все равно должна быть.

Otrava2
15.09.2010, 13:42
везет...
я вот биндю биндю
но сюржей столько что я забываю что куда забиндел(
и бегу сливаться в мили)

давай скорей выкладывай)
будет интересно глянуть

я тоже долго эксперементировал с автохоткеем
и нагой

не знаю мне ужасно не удобно нажимать на наге кнопки
недели две уже не могу привыкнуть
скрюченным большим пальцем особо не понатыкаешь)

Добавлено через 12 минут
стамина в хп все-таки первостепенный хил
во вторых не вовремя заюзанный автокаст селф хила может тебя убить (оченнь долго каст особенно в тяже)
не ставь автокаст, луше просто выбери, а кликнуть всегда успеешь.

DDTxa
15.09.2010, 13:52
угу, было бы интересно посмотреть на реализацию проверки отката и выбора по ее результатам
ждем-с :smiley)

Otrava2
15.09.2010, 13:57
я реализовал через присвоение переменной каждому спелу запуском таймера SetTimer с обнулением переменной по истечению таймера
ну и проверка этой переменной в начале

SetTimer, ray1, 15000

ray1:
rayImpale = 0
return


)) ждем другие варианты))

shtirliz
15.09.2010, 14:11
везет...
я вот биндю биндю
но сюржей столько что я забываю что куда забиндел(
и бегу сливаться в мили)

давай скорей выкладывай)
будет интересно глянуть

я тоже долго эксперементировал с автохоткеем
и нагой

не знаю мне ужасно не удобно нажимать на наге кнопки
недели две уже не могу привыкнуть
скрюченным большим пальцем особо не понатыкаешь)

Добавлено через 12 минут
стамина в хп все-таки первостепенный хил
во вторых не вовремя заюзанный автокаст селф хила может тебя убить (оченнь долго каст особенно в тяже)
не ставь автокаст, луше просто выбери, а кликнуть всегда успеешь.

Для пве такой хил очень удобно юзать....в пвп пока не участвую, т.к. умираю в 3 секунды:hapydancsmil:
Раньше тоже на наге не удобно было, но сейчас все супер. Проблема заключается в том, что НАГА предназначена в первую очередь для скилов, которые сразу юзаются. В ДФ приходится нажимать левый клик, в итоге рука напрягается лишний раз или сбивается, теряется время. Всяко автоматика быстрее нажимает.
Похожая проблема в пвп со спринтом. Не могу я держать правую кнопку и при этом постоянно нажимать левую и еще быстро крутить камеру. Вот сделаю тогл вообще будет сказка.

S R G
15.09.2010, 14:43
проверяется откачен ли скил HealSelf, если откчан, то юзаем (выбор скила + левый клик), если не откачен, то юзается скил Stamina to Health. На практике очень удобно.
в пвп ты поймешь, что это не удобно. под каждую хилку (вич брю в том числе) нужна своя кнопка. селф хил уже правильно сказали - долгий каст. ничего не можешь сделать в это время и каст не прервать.

да, и на автоклик разве что реи юзать.
По поводу макросов "выбрал стаф и выбрал закл и заюзал" - тоже только к реям имхо ибо только для реев отдельный стаф нужен.

вместо наги ждите G700 - там с удобством все супер и кнопок дофига.

shtirliz
15.09.2010, 15:03
в пвп ты поймешь, что это не удобно. под каждую хилку (вич брю в том числе) нужна своя кнопка. селф хил уже правильно сказали - долгий каст. ничего не можешь сделать в это время и каст не прервать.

да, и на автоклик разве что реи юзать.
По поводу макросов "выбрал стаф и выбрал закл и заюзал" - тоже только к реям имхо ибо только для реев отдельный стаф нужен.

вместо наги ждите G700 - там с удобством все супер и кнопок дофига.
Я считаю, что переключение оружия руками это рутина...какой смысл жать лишние клавиши, когда можно вместо трех нажать одну? Вероятность ошибки при трех нажатиях на много выше, чем нажатие одной кнопки. Если оружие уже выбрано, то по времени макрос выполняется также быстро, как нажатие одного скила, т.к. макрос запоминает состояние (если выбрано оружие, то второй раз оно не будет выбираться).

На счет долгого хила полностью согласен - надо сменить приоритет (банка, стамина в хп, селфхил)
Но в пве лучше юзать халявный хил.

S R G
15.09.2010, 15:08
чару нужно время, между выбором посоха и активацией скила - это задержки. и на них еще влиет пинг до сервера и лаги.

Otrava2
15.09.2010, 21:47
ну и где скрипт????

shtirliz
15.09.2010, 22:57
обновил пост

HappyFrag
16.09.2010, 01:49
У меня небольшая проблема со скриптом на спринт. После того как я залез в банк или могилку и т.д.. Скрипт включается на второе нажатие кнопки. Потом работает нормально. Это как нибудь лечится ? Причем побывал разные скрипты. У всех так работает ?

shtirliz
16.09.2010, 07:03
У меня небольшая проблема со скриптом на спринт. После того как я залез в банк или могилку и т.д.. Скрипт включается на второе нажатие кнопки. Потом работает нормально. Это как нибудь лечится ? Причем побывал разные скрипты. У всех так работает ?

Вчера скачал скрипт по этой проблемы, но еще не успел разобраться.
Может поможет тебе.


#IfWinActive, Darkfall Online ahk_class SFMainWindow
;IfWinActive, Darkfall Online
{

; Sprint toggle
*Lshift::
if sprint:=!sprint
SendInput {F12 down} ; F12 = sprint
else
SendInput {F12 up} ; F12 = sprint
return

; toggle GUI/Chat
~Enter::
$Xbutton1::
Suspend permit
if (GuiMode()) {
Suspend Off
; Exiting GUI mode (or chat mode)
SendInput {Xbutton1} ; Xbutton1 = gui toggle
Sleep 100
; 2nd gui toggle needed if we were in chat mode previously
if (GuiMode()) {
SendInput {Xbutton1} ; Xbutton1 = gui toggle
Sleep 100
}
; Auto-unsheathe upon exiting GUI mode (optional)
SendInput {J} ; J = a_Unsheathe_Object
Sleep 100
if (sprint)
; restore sprint status
SendInput {F12 down} ; F12 = sprint
} else {
; entering GUI mode + Chat mode
Suspend On
SendInput {Xbutton1} ; Xbutton1 = gui toggle
Sleep 100
SendInput {Enter} ; Enter = chat toggle
Sleep 100
if (sprint)
; cancel sprint status
SendInput {F12 up} ; F12 = sprint
}

GuiMode()
{
VarSetCapacity(mi,20,0)
mi:=chr(20)
DllCall("GetCursorInfo","Uint",&mi)
hCursor:=NumGet(mi,8) ; returns 0 for game-mode
return hCursor
}
return

Otrava2
16.09.2010, 07:03
на офф форуме много написано про спринт макро
http://forums.darkfallonline.com/showthread.php?t=234006&page=7


понял почему ты используешь автокаст))
не хочешь или не можешь реализовать проверку условия нажатия мыши ?

Unknowm
16.09.2010, 08:13
Самое главное ты не указал не где!
НЕ РАСЧИТЫВАЙТЕ НА МАКРОСЫ!!!!!!!!!!!!!!!! Малейший лаг, и вы всираете все из за несработки макроса. Играйте руками, тогда лаги для вас не будут фатальны!

С проблемой спринта: пропушен 1 return в скрипте, поэтому маленький косяк есть.

Максимум какие макросы нужны на данный момент: лен страйк(боковые удары с маунта) ну и 1ручка+щит(необязательно) все остальное чаще всего будет играть только в -, особенно на сиджах!

Роман Владимирович
16.09.2010, 08:20
Максимум какие макросы нужны на данный момент: лен страйк(боковые удары с маунта) ну и 1ручка+щит
реи еще, для тех у кого они есть, но опять же не обязательно.

shtirliz
16.09.2010, 09:43
на офф форуме много написано про спринт макро
http://forums.darkfallonline.com/showthread.php?t=234006&page=7


понял почему ты используешь автокаст))
не хочешь или не можешь реализовать проверку условия нажатия мыши ?
Чего я не могу и не хочу?

Добавлено через 3 минуты
Самое главное ты не указал не где!
НЕ РАСЧИТЫВАЙТЕ НА МАКРОСЫ!!!!!!!!!!!!!!!! Малейший лаг, и вы всираете все из за несработки макроса. Играйте руками, тогда лаги для вас не будут фатальны!

С проблемой спринта: пропушен 1 return в скрипте, поэтому маленький косяк есть.

Максимум какие макросы нужны на данный момент: лен страйк(боковые удары с маунта) ну и 1ручка+щит(необязательно) все остальное чаще всего будет играть только в -, особенно на сиджах!

Я только вчера начал изучать АHK:redlol) Извольте показать место, где я допустил такую оплошность, чтобы впредь не допускать такого постыдства:redlol)

По поводу лагов согласен на все 1000%%%, что длинные макросы говно. Я считаю, что макрос должен максимум делать три действия(оружие,скил,клик) в игре. Если оружие уже выбрано, то два действия(скил, клик). Макросы в AFK рулят, т.к. выполняют логику(ветвление).

А вот реи с длинной цепочкой очень сильно подвержены к лагам.

Unknowm
16.09.2010, 11:35
Я сам АХК мучаю чуть больше недели, и то потому что милишку на альте качаю

~Enter::
в конце этого метода должен быть ретурн иначе будет выполняться следующий метод. Вообщем перед ГуйМоде ретурна не хватает, на мой взгляд, хотя я не вникал в работу скрипта =) Слишком мудренно написанно, если смотреть взглядом програмиста на С# =)

shtirliz
16.09.2010, 11:48
Я сам АХК мучаю чуть больше недели, и то потому что милишку на альте качаю

~Enter::
в конце этого метода должен быть ретурн иначе будет выполняться следующий метод. Вообщем перед ГуйМоде ретурна не хватает, на мой взгляд, хотя я не вникал в работу скрипта =) Слишком мудренно написанно, если смотреть взглядом програмиста на С# =)
Мой скрипт в первом посте этой темы, другой скрипт я взял с какого-то сайта, чтобы разобраться.
Но по логике Return не нужен, т.к. ~Enter и $XButton1 переход в гуи режим, т.е. логика для них одинаковая

lil_caesar
16.09.2010, 11:48
ребята может поможет кто с макросом на аутохоткей, чтоб привыборе оружия или посоха автоматом бары разные переключались, я думаю это единственный нужный мне макрос )) пошлите в личку если есть плиз

shtirliz
16.09.2010, 11:56
ребята может поможет кто с макросом на аутохоткей, чтоб привыборе оружия или посоха автоматом бары разные переключались, я думаю это единственный нужный мне макрос )) пошлите в личку если есть плиз
#SingleInstance,Force
#MaxThreadsPerHotkey 2
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
WinActivate, Darkfall Online
Sleep, 200
#IfWinActive Darkfall Online
SoundPlay, %A_WinDir%\Media\ding.wav

return

; в игре надо сделать бинды
; Ctrl+1 - оружие
;shift+1 - бар
;по F1 будет браться ружие и менятся бар
F1::
send, ^{1}
sleep 250
Send, +{1}
return

lil_caesar
16.09.2010, 12:00
ок, спасибо, приду домой затестю, а что это за шапка такая? ее тоже в тело макроса?

#SingleInstance,Force
#MaxThreadsPerHotkey 2
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
WinActivate, Darkfall Online
Sleep, 200
#IfWinActive Darkfall Online
SoundPlay, %A_WinDir%\Media\ding.wav

shtirliz
16.09.2010, 12:24
ок, спасибо, приду домой затестю, а что это за шапка такая? ее тоже в тело макроса?

#SingleInstance,Force
#MaxThreadsPerHotkey 2
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
WinActivate, Darkfall Online
Sleep, 200
#IfWinActive Darkfall Online
SoundPlay, %A_WinDir%\Media\ding.wav

ДА, Это настройки для скрита

Otrava2
16.09.2010, 12:33
я про вот это:

HealSpells()
{
global cast_healself, dura_healself, time_healself, cast_stam2health, dura_stam2health, time_stam2health

t1 := A_TickCount - time_healself
t2 := A_TickCount - time_stam2health

if (t1 > dura_healself)
{
staff()

Send !+{1}
Sleep, 250

Send {LButton}
Sleep, %cast_healself%

time_healself := A_TickCount

тоже самое но с time_healself := A_TickCount
только при клике LButton
как будет выглядеть?

shtirliz
16.09.2010, 12:44
я про вот это:

HealSpells()
{
global cast_healself, dura_healself, time_healself, cast_stam2health, dura_stam2health, time_stam2health

t1 := A_TickCount - time_healself
t2 := A_TickCount - time_stam2health

if (t1 > dura_healself)
{
staff()

Send !+{1}
Sleep, 250

Send {LButton}
Sleep, %cast_healself%

time_healself := A_TickCount

тоже самое но с time_healself := A_TickCount
только при клике LButton
как будет выглядеть?
Нифига не понимаю тебя:hapydancsmil:

Unknowm
16.09.2010, 15:55
неважно 1 они выполняют или не 1. Если небудет ретурна, то после нажатия энтера и его отработки будет выполнена следуюшая ф-ция, а я сильно сомневаюсь что именно это и задумывалось! =)

shtirliz
16.09.2010, 16:03
неважно 1 они выполняют или не 1. Если небудет ретурна, то после нажатия энтера и его отработки будет выполнена следуюшая ф-ция, а я сильно сомневаюсь что именно это и задумывалось! =)
Чего там сомневаться? В скрипте все написано. Это же не колдовство какое-то?:redlol)
Этот код работает, как для входа чат по Enter, так и для входа/выхода в ГУИ по GUI тоглу.
В коде прямо в комментарии указано про чат.
Я сейчас с ним по разбирался и решил, что код кривой и по сути бесполезный.
Придумал свою реализацию, седня вечером потестю.

HappyFrag
16.09.2010, 17:11
Вот нормальный рабочий скрипт на спринт.


toggle = 0

~*SprintToggleHotkey::
/*
F12 should be bound to sprint, by default it is bound to shift.Change your bind ingame for sprint to F12. "SprintToggleHotkey" is a different key than F12. "SprintToggleHotkey" is the actual key you press in order to start and stop sprinting. It can not be F12.
*/
if toggle := !toggle
Send, {F12 down}
else
Send, {F12 Up}
return

~GUIHotkey::
/*
Same as below, replace "GUIHotkey" with your ingame key that toggles your GUI on and off... by default the right mouse button is your gui hotkey.
*/
If toggle = 1
{
Keywait, ``
/*
The above line also needs to be modified to change "``" to what your GUI key is. In my case it is the grave key "`"... If any other key is used it need only be put once.. i.e. if you use the right mouse button for your gui then it would be "Keywait, Rbutton" or if you used escape then "Keywait, Esc"
*/
Send, {F12 down}
}
else
toggle = 0
return

~Enter::
If toggle = 1
{
Keywait, Enter
Send, {F12 down}
}
else
toggle = 0
return

DDTxa
16.09.2010, 19:21
...
Send !+{1}
Sleep, 250

Send {LButton}
Sleep, %cast_healself%
...

юзал подобное, но с этими "слипами" беда - если фпс или пинг скачет - не берется стафф или спелл не выбирается и приходится еще раз повторять =(

S R G
17.09.2010, 05:24
А вот реи с длинной цепочкой очень сильно подвержены к лагам.
реи как раз самый простой макрос и как раз этому макросу больше всего пофиг на лаги :redlol)

shtirliz
17.09.2010, 10:15
реи как раз самый простой макрос и как раз этому макросу больше всего пофиг на лаги :redlol)
Если с перебором реев, то пофиг

Добавлено через 29 минут
Вот нормальный рабочий скрипт на спринт.


toggle = 0

~*SprintToggleHotkey::
/*
F12 should be bound to sprint, by default it is bound to shift.Change your bind ingame for sprint to F12. "SprintToggleHotkey" is a different key than F12. "SprintToggleHotkey" is the actual key you press in order to start and stop sprinting. It can not be F12.
*/
if toggle := !toggle
Send, {F12 down}
else
Send, {F12 Up}
return

~GUIHotkey::
/*
Same as below, replace "GUIHotkey" with your ingame key that toggles your GUI on and off... by default the right mouse button is your gui hotkey.
*/
If toggle = 1
{
Keywait, ``
/*
The above line also needs to be modified to change "``" to what your GUI key is. In my case it is the grave key "`"... If any other key is used it need only be put once.. i.e. if you use the right mouse button for your gui then it would be "Keywait, Rbutton" or if you used escape then "Keywait, Esc"
*/
Send, {F12 down}
}
else
toggle = 0
return

~Enter::
If toggle = 1
{
Keywait, Enter
Send, {F12 down}
}
else
toggle = 0
return

Идея хорошая, но скрипт не работает.

Вот рабочий скрипт


toggle = 0

sprint()
{
global toggle
if (toggle = 0) {
toggle = 1
Send, {F12 down}
} else {
toggle = 0
Send, {F12 Up}
}
}

processGUI()
{
global toggle
if (toggle = 1)
{
Keywait, Escape
Send, {F12 Up}
}
toggle = 0
}

processChat()
{
global toggle
if (toggle = 1)
{
Keywait, Enter
Send, {F12 Up}
}
toggle = 0
}

~*RButton:: sprint()
~Escape:: processGUI()
~Enter:: processChat()

return

shtirliz
20.09.2010, 09:34
За выходные много успел натестить скрипт. Пришел к выводу, что клик мышкой в макросе лишний. Лучше самому кликать, а макрос юзать только для смены оружия и выбора скила. Автохоткей на длинных макросах дико тупит:tonq2).

Otrava2
20.09.2010, 09:57
а как тогда включать таймер?
надо как-то включать таймер только после
клика мышки

я оставил автоклик только на вирлвинды

S R G
22.09.2010, 23:05
На счет долгого хила полностью согласен - надо сменить приоритет (банка, стамина в хп, селфхил)
Но в пве лучше юзать халявный хил.
да в пвп тож стамина то хп не всегда приоритетно - ибо стамины мб оч мало, а стамина полюбасу важнее, чем ХП. все зависит от ситуевины. да и банок столько не напасешься. чтоб перед каждой хилкой их юзать. да и намного чаще банка со стамой более полезна чем с ХП, а иногда и с манной. так чтаааа все на отдельные кнопки :redlol)

HappyFrag
26.09.2010, 06:04
Выложите нормальный скрипт на Whirlwind( чтобы при нажатии кнопки срабатывал Whirlwind и менялась панелька)

Remu
01.10.2010, 03:44
да в пвп тож стамина то хп не всегда приоритетно - ибо стамины мб оч мало, а стамина полюбасу важнее, чем ХП. все зависит от ситуевины. да и банок столько не напасешься. чтоб перед каждой хилкой их юзать. да и намного чаще банка со стамой более полезна чем с ХП, а иногда и с манной. так чтаааа все на отдельные кнопки :redlol)


вообщем-то всё можно всегда на одну кнопку уместить :)

например у меня в уо было на одну кнопку :

heal spell , cure spell, greatercure spell, поушены все, яблоки, паучи, отхил маунта моего, блесс, ремув курс, клинс бай фаер, crossheal тех с кем я бегал, cure тех с кем я бегал, стрелка на себя... в общем полный набор. ;-)

это вопрос желания и фантазии обычно =)
единственное ограничение в ДФ это хотбар, но если его держать развёрнутым то ограничений на самом деле никаких нет ;-) и такую же кнопку можно сделать в ДФ

Рейтинг@Mail.ru